home *** CD-ROM | disk | FTP | other *** search
/ CD ROM Paradise Collection 4 / CD ROM Paradise Collection 4 1995 Nov.iso / asm / alib11b.zip / CODE1.ZIP / DISPTEXT / CRTUTIL.ASM < prev    next >
Assembly Source File  |  1994-10-04  |  6KB  |  238 lines
  1.     page    66,132
  2.  
  3. comment 
  4. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( DISPLAY )
  5. GET_ANSI_COLOR - get color attribute used by ANSI driver.
  6. ;
  7. ; inputs:    none
  8. ; output:    AH = color attribute
  9. ;* * * * * * * * * * * * * *
  10. 
  11.     public    get_ansi_color
  12. GET_ANSI_COLOR    PROC    FAR
  13.     APUSH   BP,BX,CX,DX
  14.     XOR     BH,BH
  15.     MOV     AH,03
  16.     INT     10h            ;get cursor position (dx) and size (cx)
  17.     PUSH    DX            ;save origional cursor position
  18.     CALL    read_cursor_at_0
  19.     PUSH    AX            ;save char. read using bios
  20. ;
  21. ; setup to write char. using dos call
  22. ;    
  23.     PUSH    DS            ;save our segment
  24.     MOV     AX,CS        ;set segment
  25.     MOV     DS,AX        ;  to -cs:-
  26.     MOV     BX,0001        ;select stdout
  27.     
  28.     CALL    GAC_1        ;put address on stack
  29. GAC_1:
  30.     POP     DX            ;set dx= offset l_21b2
  31.     MOV     CX,0001
  32.     MOV     AH,40h
  33.     INT     21h            ;write stdout(bx) 1 byte(cx) data at ds:dx
  34.     CALL    read_cursor_at_0
  35.     POP     DS            ;restore data segment
  36.     MOV     BP,AX        ;save char. read using dos
  37.     XOR     BH,BH
  38.     POP     AX            ;restore char. read using bios
  39.     MOV     BL,AH        ;move bios color to -> bl
  40.     MOV     AH,09
  41.     MOV     CX,0001
  42.     PUSH    BP            ;save char. read using dos
  43.     INT     10h            ;write char.(al) bl=bios color bh=page cx=repeat
  44.     POP     BP            ;restore char. read using dos
  45.     POP     DX            ;restore origional cursor position
  46.     MOV     AH,02        ;
  47.     PUSH    BP            ;save char. read using dos
  48.     INT     10h            ;restore origional cursor posn
  49. ;                first pop of -ax- restores char read using DOS
  50.     APOP    AX,DX,CX,BX,BP
  51.     RETF
  52. GET_ANSI_COLOR    ENDP
  53.  
  54. ;----------------------    
  55. ; read_cursor_at 0 - read character at cursor position
  56. ;  inputs: none
  57. ;  output: ax = character
  58. ;
  59. read_cursor_at_0:    
  60.     MOV     AH,02
  61.     XOR     DX,DX         ;set cursor address -> 0
  62.     XOR     BH,BH        ;select page 0
  63.     INT     10h            ;set cursor position from -dx- bh=page
  64.     MOV     AH,08
  65.     INT     10h            ;read character & color at cursor -> ax
  66.     RET
  67. comment 
  68. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( DISPLAY )
  69. CURSOR_ - Move cursor and set size to standard underscore.
  70. ;
  71. ; inputs:    DH = row
  72. ;            DL = column
  73. ;            
  74. ; outputs:   register -ax- is modified
  75. ; 
  76. ;* * * * * * * * * * * * * *
  77. 
  78.     public    cursor_
  79. CURSOR_    PROC    FAR
  80.     mov    al,0
  81.     jmp    cursor_entry
  82. CURSOR_    ENDP
  83. comment 
  84. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( DISPLAY )
  85. SHOW_CURSOR - move cursor to (row, col) and update cursor shape
  86. ;
  87. ; inputs:    DH = row offset from top of screen
  88. ;            DL = column offset from left side
  89. ;
  90. ; outputs:   register -ax- modified
  91. ;
  92. ; notes:     Cursor shape is underscore if INSERT is off, large block
  93. ;            if INSERT is on.
  94. ;* * * * * * * * * * * * * *
  95. 
  96.     public    SHOW_CURSOR
  97. SHOW_CURSOR    PROC    FAR
  98.      mov     al,80h
  99. cursor_entry:
  100.     pushf
  101.     APUSH   BP,BX,CX,DX,SI,ES
  102.     MOV     AH,0Fh
  103.     INT     10h            ;get video mode -> al=mode bh=page ah=pixels
  104.     MOV     AH,02
  105.     INT     10h            ;set cursor position -> -dx-
  106.     XOR     AH,AH
  107.  
  108.     mov     al,cs:lib_info.crt_rows
  109.     mov     bx,cs:lib_info.crt_seg
  110.  
  111.     mov     cx,0
  112.     mov     es,cx
  113.     MOV     CX,0507h
  114.     MOV     DX,WORD PTR ES:[0463h] ;get crt port address  mono=3b4 color=3d4
  115.     CMP     DX,03B4h        ;check if mono display
  116.     JNZ     c_color        ; jmp if color display
  117.     CMP     AL,1Dh        ;check if rows = 29
  118.     JGE     c_color        ; jmp if 29 rows or more
  119.     MOV     CX,0C0Dh
  120.     MOV     AL,2Ah
  121. c_color:
  122.     AND     BL,BYTE PTR ES:[0417h] ;
  123.     JZ      c_skip
  124.     SHR     CH,1
  125. c_skip:
  126.     CMP     AL,1Dh
  127.     JB      c_bios_set
  128.     CMP     AL,2Dh    ; '-'
  129.     JB      c_wrt_port
  130. c_bios_set:
  131.     MOV     AH,01
  132.     INT     10h            ;set text mode cursor size (cx)
  133.     JMP     c_exit
  134. c_wrt_port:
  135.     MOV     AL,0Ah
  136.     MOV     AH,CH
  137.     OUT     DX,AX
  138.     INC     AL
  139.     MOV     AH,CL
  140.     OUT     DX,AX
  141.     MOV     WORD PTR ES:[0460h],CX
  142. c_exit:
  143.     APOP    ES,SI,DX,CX,BX,BP
  144.     POPF
  145.     RETF
  146. SHOW_CURSOR    ENDP
  147. comment 
  148. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( DISPLAY )
  149. HIDE_CURSOR - make hardware cursor invisible at present location
  150. ;
  151. ; inputs:    none
  152. ; outputs:   none
  153. ;
  154. ;* * * * * * * * * * * * * *
  155. 
  156.     public    HIDE_CURSOR
  157. HIDE_CURSOR    PROC    FAR
  158.     APUSH   AX,CX
  159.     MOV     CX,2020h
  160.     MOV     AH,01
  161.     PUSH    BP
  162.     INT     10h
  163.     POP     BP
  164.     APOP    CX,AX
  165.     RETF
  166. HIDE_CURSOR    ENDP
  167. comment 
  168. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( DISPLAY )
  169. BLINK_ON:  enable blinking attriutes
  170. ;
  171. ; inputs: none
  172. ; output: none
  173. ;
  174. ; notes:  The opposite of blink is intenisified colors.  The normal default
  175. ;         is blink on.
  176. ;* * * * * * * * * * * * * *
  177. 
  178.     public    BLINK_ON
  179. BLINK_ON        PROC    FAR
  180.     PUSH    BX
  181.     MOV     BX,0001
  182.     JMP     blink_entry
  183. BLINK_ON ENDP
  184. comment 
  185. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( DISPLAY )
  186. BLINK_OFF:  disable blinking attriutes
  187. ;
  188. ; inputs: none
  189. ; output: none
  190. ;
  191. ; note: Blink off turns intensified color selection on.  The default at
  192. ;       boot time is blink on.
  193. ;* * * * * * * * * * * * * *
  194. 
  195.     public    BLINK_OFF
  196. BLINK_OFF    PROC    FAR
  197.     PUSH    BX
  198.     MOV     BX,0000
  199. blink_entry:
  200.     APUSH   AX,DX,ES
  201.     SUB     AX,AX
  202.     MOV     ES,AX
  203.     MOV     AL,BYTE PTR ES:[0487h]    ;get ega/vga control flag
  204.     OR      AL,AL
  205.     JNZ     ega_vga_blink            ;jmp if flag seems active
  206. ;
  207. ; program mono/cga controller directly
  208. ;     
  209.     MOV     DX,WORD PTR ES:[0463h]    ;get crt port address
  210.     ADD     DL,04
  211.     MOV     AL,BYTE PTR ES:[0465h]    ;current mode select register setting
  212.     OR      BX,BX            ;bx=0(BLINK_OFF)  bx=1(BLINK_ON)
  213.     JZ      cga_mono_boff        ;jmp if blink off request
  214.     OR      AL,20h
  215.     JMP     cga_mono_bon
  216. ;
  217. ; blink off
  218. ;    
  219. cga_mono_boff:
  220.     AND     AL,0DFH            ;disable blink bit
  221. cga_mono_bon:
  222.     OUT     DX,AL
  223.     MOV     BYTE PTR ES:[0465h],AL    ;set new mode select reg data
  224.     JMP     blink_exit
  225. ;
  226. ; ega/vga blink setting
  227. ;    
  228. ega_vga_blink:
  229.     MOV     AX,1003h
  230.     INT     10h                ;bx=0(BLINK_OFF)  bx=1(BLINK_ON)
  231. blink_exit:
  232.     APOP    ES,DX,AX
  233.     POP     BX
  234.     RETF
  235. BLINK_OFF    ENDP
  236.  
  237.     end
  238.